亚洲av色香蕉一区二区三区,十四以下岁毛片带血a级,亚洲 校园 欧美 国产 另类,亚洲av日韩av一区谷露,色欲av无码一区二区三区

  • 相關(guān)軟件
    >把HTML表單提交的數(shù)據(jù)轉(zhuǎn)化成XML文件　創(chuàng)建者：webmaster　更新時間：2005-06-08 23:58

    通常，在asp中進(jìn)行的form表單提交的數(shù)據(jù)都被寫進(jìn)數(shù)據(jù)庫管理系統(tǒng)中去，如果你想要你的數(shù)據(jù)是方便攜帶的數(shù)據(jù)，你可以把它寫進(jìn)一個XML文件中去。這種方法是跨平臺的，因此你所收集的信息不需要進(jìn)行轉(zhuǎn)換。
    為了實(shí)現(xiàn)上面的想法，你必須先利用Microsoft XMLDOM建立一個XML文件，Microsoft XMLDOM對象有一個擴(kuò)展對象庫，它可以創(chuàng)建組成XML文件所需要的元素、屬性、屬性值。
    當(dāng)XMLDOM對象實(shí)例化以后，必須對各個元素進(jìn)行引用來建立XML的結(jié)構(gòu)，下面的例子就是先建立根元素，并把她追加到XML文件中；然后創(chuàng)建各個子元素，并追加元素的屬性值。最后保存為XML文件。
    實(shí)例化 Microsoft XMLDOM Object: <%
    Dim objDom
    Dim objRoot
    Dim objChild1
    Dim objChild2
    Dim objPI
    Set objDom = Server.CreateObject("Microsoft.XMLDOM")
    Set objRoot = objDom.createElement("rootElement")

    objDom.appendChild objRoot
    Set objChild1 = objDom.createElement("childElement1")

    objRoot.appendChild objChild1
    Set objChild2 = objDom.createElement("childElement2")

    objRoot.appendChild objChild2

    Set objPI = objDom.createProcessingInstruction("xml","version='1.0'")
    objDom.insertBefore objPI, objDom.childNodes(0)
    objDom.Save "c:\MyXMLDoc.xml"
    %>



    一旦你保存了文件，用IE5+打開后，樣式如下[當(dāng)然，屬性還沒有被賦值]：
    MyXMLDoc.xml: <?xml version="1.0"?>
    <rootElement>
    <childElement1 />
    <childElement2 />
    </rootElement>



    　

    下面我們來看看怎樣利用這個對象來存儲用戶的輸入信息。

    首先建立輸入表單的頁面。
    EnterContact.html: <html>
    <head>
    <title>
    通訊信息
    </title>
    </head>
    <body>
    <form action="processForm.asp" method="post">
    <h3>請輸入您的通訊信息：</h3>
    姓 名: <input type="text" id="Name" name="姓名"><br>
    性 別: <input type="text" id="sexName" name="性別"><br>
    地 址: <input type="text" id="address" name="地址"><br>
    工作單位: <input type="text" id="company" name="工作單位"><br>
    電 話: <input type="text" id="phone" name="電話"><br>
    電子郵件: <input type="text" id="email" name="電子郵件"><br>
    <input type="submit" id="btnSub" name="btnSub" value="提交"><br>
    </form>
    </body>
    </html>


    然后編寫ASP代碼，遍歷表單元素，并把輸入的信息寫進(jìn)XML文件。
    processForm.asp: <%
    '--------------------------------------------------------------------
    '函數(shù) "ConvertFormtoXML"接收傳遞的參數(shù)。
    'strXMLFilePath - XML存放的物理地址。
    'strFileName - 要保存的XML文件的名字。
    '--------------------------------------------------------------------
    Function ConvertFormtoXML(strXMLFilePath, strFileName)
    '定義本地變量.
    Dim objDom
    Dim objRoot
    Dim objField
    Dim objFieldValue
    Dim objattID
    Dim objattTabOrder
    Dim objPI
    Dim x

    '實(shí)例化Microsoft XMLDOM對象.
    Set objDom = server.CreateObject("Microsoft.XMLDOM")
    objDom.preserveWhiteSpace = True

    '創(chuàng)建XML文檔的根元素contact，并追加到XML文檔中。
    Set objRoot = objDom.createElement("通訊錄")
    objDom.appendChild objRoot

    '遍歷Request對象Form元素的集合。
    For x = 1 To Request.Form.Count

    If instr(1,Request.Form.Key(x),"btn") = 0 Then

    '創(chuàng)建元素 "field".
    Set objField = objDom.createElement("field")

    '創(chuàng)建屬性 "id".
    Set objattID = objDom.createAttribute("id")

    '設(shè)定id屬性的值等于Form中各元素的值。
    objattID.Text = Request.Form.Key(x)

    'setAttributeNode 方法把id屬性值追加到field元素。
    objField.setAttributeNode objattID

    '創(chuàng)建屬性taborder。
    Set objattTabOrder = objDom.createAttribute("taborder")

    '設(shè)定taborder的屬性值
    objattTabOrder.Text = x

    '把taborder的屬性值追加到field元素中去。
    objField.setAttributeNode objattTabOrder

    '創(chuàng)建一個新的元素field_value.
    Set objFieldValue = objDom.createElement("field_value")

    '賦值
    objFieldValue.Text = Request.Form(x)

    '追加field元素為根元素的子元素。
    objRoot.appendChild objField

    '追加field_value做為子元素的內(nèi)容
    objField.appendChild objFieldValue
    End If
    Next


    '創(chuàng)建xml聲明
    Set objPI = objDom.createProcessingInstruction("xml", "version='1.0' encoding='gb2312'")

    '把xml生命追加到xml文檔
    objDom.insertBefore objPI, objDom.childNodes(0)

    '保存xml文件
    objDom.save strXMLFilePath & "\" & strFileName

    '釋放所有對象所引用的值
    Set objDom = Nothing
    Set objRoot = Nothing
    Set objField = Nothing
    Set objFieldValue = Nothing
    Set objattID = Nothing
    Set objattTabOrder = Nothing
    Set objPI = Nothing
    End Function


    '發(fā)生錯誤時繼續(xù)執(zhí)行
    On Error Resume Next

    '調(diào)用函數(shù)ConvertFormtoXML把文件存放到指定的文件目錄和文件名。
    ConvertFormtoXML "D:\aspexam","Contact.xml"

    '如果發(fā)生錯誤，提示用戶，否則報告成功。
    If err.number <> 0 then
    Response.write("保存form值出現(xiàn)錯誤?。?！")
    Else
    Response.write("提交成功！！")
    End If
    %>

    用IE5+打開Contact.xml文件.    相關(guān)文章
    本頁查看次數(shù):